2015年09月13日

ESP8266 SDKのJSON APIを使ってみた

前回はオープンソースのJSONライブラリについて紹介しましたが、本家のESP8266 SDKにも、JSONライブラリが入っています。

今回は前回の続きということでこのライブラリを紹介しますが、最初に結論を書いておくと、このライブラリは空のオブジェクト({})をうまく扱えないバグがあります。
また、使いやすさという意味ではArduinoJsonやaJsonにやや劣ります。
その代わり、解析したいJSONデータに合わせてプログラムコードをチューニングすることも可能です。
実際に使用する場合は、SDKのライブラリをリンクするよりも、大元のソースコードをダウンロードしたほうがデバッグしやすいと思います。

前回と同じテストデータを使った場合の星取表は下のようになります。

TEST1TEST2TEST3TEST4
ArduinoJsonOKOKNGNG
aJsonOKNGOKOK
ESP8266 SDK APIOKNGOKOK


このライブラリのAPIの解説はSDKに付属しているプログラミングガイドの中にあります。
現時点でのファイル名は「2C-ESP8266__SDK__Programming Guide__EN_v1.3.0.pdf」となっています。
このガイドの5.2節がJSON関連APIの解説になっています。
ただ、ガイドではAPIそのものが簡単に解説されているだけで、あまり親切ではありません。

このSDKのライブラリとインクルードファイルはArduino IDEの中にも含まれています。
JSON関連のインクルードファイルが入っているフォルダは

%USERPROFILE%\AppData\Roaming\Arduino15\packages\esp8266\hardware\esp8266\1.6.5-947-g39819f0\tools\sdk\include\json

です。
ヘッダファイルのコメントを見ると、最後のほうに
This file is part of the Contiki operating system.

とあります。
つまり、このライブラリは「Contiki」という別のプロジェクトから持ってきたものらしいことが分かります。

探してみると、このライブラリのオリジナルは

contiki/apps/json at master ・ contiki-os/contiki

であるようです。ソースコードも公開されています。


SDKのプログラミングガイドの解説だけでは、どうも内容が分かりにくかったのですが、このソースコードを眺めるとライブラリの使い方が分かってきました。
APIにはJSONの解析と生成の両方が含まれていますが、関心は解析のほうにありますので、解析側のAPIのみ使ってみます。


まず、先にソースコードを掲載しておきます。

#include <limits.h>
#include <errno.h>
#define JSONPARSE_CONF_MAX_DEPTH 50
#ifdef ESP8266
extern "C" {
#include "json/jsonparse.h"
}
#endif
#define TEST1 "{\"obj1\":\"abc\"}"
#define TEST2 "{\"obj1\":{}, \"obj2\":[{}], \"obj3\":null}"
//TEST3, TEST4 derived from http://json.org/example.html
#define TEST3 "{\"glossary\": {\"title\": \"example glossary\",\"GlossDiv\": {\"title\": \"S\",\"GlossList\": {\"GlossEntry\": {\"ID\": \"SGML\",\"SortAs\": \"SGML\",\"GlossTerm\": \"Standard Generalized Markup Language\",\"Acronym\": \"SGML\",\"Abbrev\": \"ISO 8879:1986\",\"GlossDef\": {\"para\": \"A meta-markup language, used to create markup languages such as DocBook.\",\"GlossSeeAlso\": [\"GML\", \"XML\"]},\"GlossSee\": \"markup\"}}}}}"
#define TEST4 "{\"widget\": {\"debug\": \"on\",\"window\": {\"title\": \"Sample Konfabulator Widget\",\"name\": \"main_window\",\"width\": 500,\"height\": 500    },\"image\": {\"src\": \"Images/Sun.png\",\"name\": \"sun1\",\"hOffset\": 250,\"vOffset\": 250,\"alignment\": \"center\"    },\"text\": {\"data\": \"Click Here\",\"size\": 36,\"style\": \"bold\",\"name\": \"text1\",\"hOffset\": 250,\"vOffset\": 100,\"alignment\": \"center\",\"onMouseUp\": \"sun1.opacity = (sun1.opacity / 100) * 90;\"    }}} "

#define JSON_TEST_DATA TEST1

void test_sdk_json() {
 char json[] = JSON_TEST_DATA;
 jsonparse_state state;
 int c;
 int valueType;

 jsonparse_setup(&state, json, strlen(json));
 while((c = jsonparse_next(&state)) != JSON_TYPE_ERROR) {
   char token[256];
   long value;
   
   switch(c) {
     case JSON_TYPE_ARRAY:
     case JSON_TYPE_OBJECT:
     case JSON_TYPE_PAIR:
       Serial.print(char(c));
       break;
     case JSON_TYPE_PAIR_NAME:
     case JSON_TYPE_STRING:
       valueType = jsonparse_copy_value(&state, token, 255);
       Serial.print(String('"') + token + '"');
       break;
     case JSON_TYPE_INT:
     case JSON_TYPE_NUMBER:
       value = jsonparse_get_value_as_long(&state);
       Serial.print(value, DEC);
       break;
     case JSON_TYPE_NULL:
       Serial.print("null");
       break;
     case JSON_TYPE_TRUE:
       Serial.print("true");
       break;
     case JSON_TYPE_FALSE:
       Serial.print("false");
       break;
     default:
       Serial.print(char(c));
   }
 }
 if (c == JSON_TYPE_ERROR) {
   String errStr;

   Serial.println();
   switch(state.error) {
     case JSON_ERROR_OK: errStr="OK"; break;
     case JSON_ERROR_SYNTAX: errStr="Syntax Error"; break;
     case JSON_ERROR_UNEXPECTED_ARRAY: errStr="Unexpected array"; break;
     case JSON_ERROR_UNEXPECTED_END_OF_ARRAY: errStr="Unexpected end of array"; break;
     case JSON_ERROR_UNEXPECTED_OBJECT: errStr="Unexpected object"; break;
     case JSON_ERROR_UNEXPECTED_STRING: errStr="Unexpected string"; break;
   }
   Serial.println(errStr);

   if (state.depth < JSONPARSE_MAX_DEPTH) {
     // dump json stack
     int i;
     for(i = 0; i < state.depth; i++) {
       Serial.print(state.stack[i]);
     }
     Serial.println();
  } else {
     Serial.println("JSON too deep");
   }
 }
}

void setup() {
 Serial.begin(115200);
 Serial.println("");
 Serial.println(String("Test data: ")+JSON_TEST_DATA);

 Serial.println("\n\ntesting SdK json API\n");
 test_sdk_json();
}

void loop() {
 // put your main code here, to run repeatedly:
 delay(100);
}

aJsonやArduinoJsonでは、最初にJSON文字列を渡して一気に全体をパースしていました。
一方、このSDKのライブラリでは、文字列を少しずつ読み進めていくループを自分で書く必要があります。

最初の
jsonparse_setup(&state, json, strlen(json));

は変数の初期値を設定するだけで、そのあと
c = jsonparse_next(&state)

を呼ぶたびに、新しいデータを読み込みます。

このとき、空白はまとめて読み飛ばされ、文字列や数値など文字に分解できない「アトム」はまとめて読み込まれます。
自分のプログラムで行いたい処理は、このwhileループの中で行うことになります。

"{"と"}"のような対応する入れ子構造はパーサがチェックし、文法ミスがあればエラーを返します。

また、このライブラリで扱えるデータの入れ子構造の最大値は、デフォルトでは10段です。
TEST3で使うデータはもう少し階層が深いので、
#define JSONPARSE_CONF_MAX_DEPTH 50

で最大を50にしています。


なお、これはESP8266用Arduinoの不備だと思われますが、上記のスケッチをコンパイルすると「strtoulが無い」というエラーが出ます。
これについては、以下のやり取りが参考になります。

cstdlib function strtoul not supported ・ Issue #608 ・ esp8266/Arduino

要は、ESP8266用Arduinoのlibcにstrtoulが入ってなかったということのようです。
今回は、とりあえず以下からstrtoul()関数を丸ごとコピーしてスケッチの末尾へ貼り付けました。

Arduino/libc_replacements.c at f73457de0d6b703b96a809e48b2163f16aa367e8 ・ kzyapkov/Arduino

また、strtoulを正しくコンパイルするために、

#include <limits.h>
#include <errno.h>
の2つのファイルをインクルードしています。


さらに、ESP8266用Arduinoの標準ではSDKのJSONライブラリをリンクしてくれませんので、これについても修正が必要です。

修正は、
%USERPROFILE%\AppData\Roaming\Arduino15\packages\esp8266\hardware\esp8266\1.6.5-947-g39819f0

のフォルダの中の
platform.txt

の中の下記の部分を追記しました。(上に掲載したスケッチからは省略しています。)
compiler.c.elf.libs=-lm -lgcc -lhal -lphy -lnet80211 -llwip -lwpa -lmain -lpp -lsmartconfig -lwps -lcrypto -ljson

(これが正しいやり方なのかどうかは分かりません。)
この修正を有効にするにはIDEの再起動が必要です。
posted by boochow at 22:34| Comment(0) | ESP8266 | このブログの読者になる | 更新情報をチェックする

ArduinoJsonとaJsonをESP8266で使う際の比較

インターネットから情報を取ってきてESP8266で処理しようとすると、データ構造が比較的シンプルなJSON形式は便利です。
以前も、為替情報をJSONで取得して表示させてみました。

ESP8266版Arduinoでネットから情報を取ってきてLCDに表示する: 楽しくやろう。

ただ、比較的大きなデータになる場合もあり、マイコンで安定して扱えるわけではないようです。

オープンソースで公開されていてArduinoで利用実績があるJSONのパーサとしては、以前使用したArduinoJsonや、同様にArduinoで使えるJSONライブラリのaJsonがあります。

両方とも使ってみましたが、

・ArduinoJson 小さなデータに対しては割と安定している。APIも分かりやすい。
・aJson 大きなデータでも比較的安定しているが、イレギュラーなデータにはちょっと弱い。

という印象になりました。
その比較をメモ代わりに記事にしておきます。


なお最初にお断りしておきますが、これらのライブラリが動作しない場合でも、ライブラリ自体に問題があるのか、ライブラリが呼び出しているESP8266用Arduinoのライブラリ側に問題があるのかは分かりません。
Arduino IDEはデバッガが全く利用できないので、原因を追いかけられないのが歯がゆいところです。


テストとしては、4つのJSONデータを上記の2つのパーサで解析できるか試してみました。
その結果をまとめると、以下のような星取り表になります。

TEST1TEST2TEST3TEST4
ArduinoJsonOKOKNGNG
aJsonOKNGOKOK


ArduinoJsonは今月最新版の5.0がリリースされたところですが、この記事では4.0を使っています。
aJsonのほうはバージョン1.0を使っています。


使ったテストデータは以下の通りです。
TEST3とTEST4は、JSONのページサンプルから取ってきています。

TEST1{"obj1":"abc"}
TEST2{"obj1":{}, "obj2":[{}], "obj3":null}
TEST3{"glossary": {"title": "example glossary","GlossDiv": {"title": "S","GlossList": {"GlossEntry": {"ID": "SGML","SortAs": "SGML","GlossTerm": "Standard Generalized Markup Language","Acronym": "SGML","Abbrev": "ISO 8879:1986","GlossDef": {"para": "A meta-markup language, used to create markup languages such as DocBook.","GlossSeeAlso": ["GML", "XML"]},"GlossSee": "markup"}}}}}
TEST4{"widget": {"debug": "on","window": {"title": "Sample Konfabulator Widget","name": "main_window","width": 500,"height": 500 },"image": {"src": "Images/Sun.png","name": "sun1","hOffset": 250,"vOffset": 250,"alignment": "center" },"text": {"data": "Click Here","size": 36,"style": "bold","name": "text1","hOffset": 250,"vOffset": 100,"alignment": "center","onMouseUp": "sun1.opacity = (sun1.opacity / 100) * 90;" }}}


JSONデータ自体が正しいフォーマットになっているかどうかは、以下のリンクのようなオンラインのJSONパーサで確認できます。

Json Parser Online

使用したスケッチファイルも一応掲載しておきます。
4つのテストの1つしか実行しないようになっていますので、
#define JSON_TEST_DATA TEST1

のところを適宜変更してください。
また、ArduinoJsonのテストが失敗してハングアップすると、aJsonのテストは実行されません。
これも、適宜コメントアウトするなどの対処が必要です。


#include <ArduinoJson.h>
#include <aJSON.h>

#define TEST1 "{\"obj1\":\"abc\"}"
#define TEST2 "{\"obj1\":{}, \"obj2\":[{}], \"obj3\":null}"
//TEST3, TEST4 derived from http://json.org/example.html
#define TEST3 "{\"glossary\": {\"title\": \"example glossary\",\"GlossDiv\": {\"title\": \"S\",\"GlossList\": {\"GlossEntry\": {\"ID\": \"SGML\",\"SortAs\": \"SGML\",\"GlossTerm\": \"Standard Generalized Markup Language\",\"Acronym\": \"SGML\",\"Abbrev\": \"ISO 8879:1986\",\"GlossDef\": {\"para\": \"A meta-markup language, used to create markup languages such as DocBook.\",\"GlossSeeAlso\": [\"GML\", \"XML\"]},\"GlossSee\": \"markup\"}}}}}"
#define TEST4 "{\"widget\": {\"debug\": \"on\",\"window\": {\"title\": \"Sample Konfabulator Widget\",\"name\": \"main_window\",\"width\": 500,\"height\": 500    },\"image\": {\"src\": \"Images/Sun.png\",\"name\": \"sun1\",\"hOffset\": 250,\"vOffset\": 250,\"alignment\": \"center\"    },\"text\": {\"data\": \"Click Here\",\"size\": 36,\"style\": \"bold\",\"name\": \"text1\",\"hOffset\": 250,\"vOffset\": 100,\"alignment\": \"center\",\"onMouseUp\": \"sun1.opacity = (sun1.opacity / 100) * 90;\"    }}} "

#define JSON_TEST_DATA TEST1

void test_arduinojson(){
 char json[] = JSON_TEST_DATA;
 StaticJsonBuffer<4000> jsonBuffer;

 JsonObject& root = jsonBuffer.parseObject(json);
 if (!root.success()) {
   Serial.println("parseObject() failed");
   return;
 }
 root.printTo(Serial);
}

void test_ajson() {
 char json[] = JSON_TEST_DATA;

 aJsonObject* root = aJson.parse(json);
 if (root == NULL) {
   Serial.println("aJson.parse() failed");
   return;
 }
 Serial.println(aJson.print(root));
}

void setup() {
 Serial.begin(115200);
 Serial.println("");
 Serial.println(String("Test data: ")+JSON_TEST_DATA);

 Serial.println("\n\ntesting ArduinoJson\n");
 test_arduinojson();

 Serial.println("\n\ntesting aJson\n");
 test_ajson();
}

void loop() {
 // put your main code here, to run repeatedly:
 delay(100);
}



実行にはArduinoJsonとaJsonの2つのライブラリが必要です。
ArduinoJsonは以下、

bblanchon/ArduinoJson

aJsonは以下

interactive-matter/aJson

からダウンロードできます。
また、aJsonの使い方の解説は以下にあります。

aJson – Handle JSON with Arduino − Interactive Matter Lab

なお、aJsonはコンパイル時にlibm.aのリンクエラーが発生しました。
これは現在のESP8266用Arduino環境の不具合のようで、以下に解決策が出ていました。

Stable version libm.a compilation error ・ Issue #612 ・ esp8266/Arduino

https://files.gitter.im/esp8266/Arduino/Abqa/libm.a.tbzをダウンロードして、解凍して得られるlibm.aを元のlibm.aと置き換えれば修復できます。

libm.aの入っているフォルダは、
%USERPROFILE%\AppData\Roaming\Arduino15\packages\esp8266\tools\xtensa-lx106-elf-gcc\1.20.0-26-gb404fb9\xtensa-lx106-elf\lib

になります。
posted by boochow at 17:12| Comment(0) | ESP8266 | このブログの読者になる | 更新情報をチェックする

2015年09月05日

ESP8266にカラーTFT液晶をSPI接続してみる

esp826607-01.jpg

ESP8266にキャラクタ液晶はちゃんとつながりましたので、今度は先日使ったカラーTFT LCD(aitendo M-Z18SPI-2P)をつないでみました。

環境自体はArduinoですので接続だけで済むかも、と期待したのですが、残念ながらこれに使用するライブラリ(Adafruit_ST7735)はそのままではコンパイルできませんでした。

しかし、幸いなことに既にこのライブラリをESP8266にポーティングしている方がいました。

lcd: add support for the ESP8266. ・ nzmichaelh/Adafruit-ST7735-Library@999f5ff

この修正は他の修正と競合するらしく、現時点ではまだ本体へ統合されていません。
使ってみるには、以下からこの修正済みライブラリをダウンロードします。

nzmichaelh/Adafruit-ST7735-Library

なお、オリジナルと同様、このライブラリはM-Z18SPI-2Pでは画面にゴミが残りますので、以前に書いた修正をこのライブラリに対して行います。

Arduino(9) Adafruit_ST7735ライブラリの修正(aitendoの1.8型LCD用): 楽しくやろう。


このライブラリを使って、付属のスケッチ例「graphicstest」を動かしてみました。

結線は以下のようになります。
例によって、この図はプログラム書き込み等に必要な共通部分は省略しています。
省略部分はこちらを参照してください。

ESP8266-Z18SPI.png


信号同士の接続は以下のようになっています。

LCD / ESP8266
RST / IO5
A0 / IO4
SDA / IO13
SCK / IO14
CS / IO15


graphicstestスケッチのソースコードも、この結線を反映するように変更します。
また、画面にゴミが残らない修正を使うため、LCDの種別はBLUETABに変更します。
赤字が変更部分です。
IO13とIO14はデフォルトの結線ですので、記述しなければSDAとSCKに接続されたものとして扱われます。
デフォルトの結線については別記事で紹介しました

// For the breakout, you can use any 2 or 3 pins
// These pins will also work for the 1.8" TFT shield
#define TFT_CS 15
#define TFT_RST 5
// you can also connect this to the Arduino reset
// in which case, set this #define pin to 0!
#define TFT_DC 4

// Option 1 (recommended): must use the hardware SPI pins
// (for UNO thats sclk = 13 and sid = 11) and pin 10 must be
// an output. This is much faster - also required if you want
// to use the microSD card (see the image drawing example)
Adafruit_ST7735 tft = Adafruit_ST7735(TFT_CS, TFT_DC, TFT_RST);

// Option 2: use any pins but a little slower!
#define TFT_SCLK 13 // set these to be whatever pins you like!
#define TFT_MOSI 11 // set these to be whatever pins you like!
//Adafruit_ST7735 tft = Adafruit_ST7735(TFT_CS, TFT_DC, TFT_MOSI, TFT_SCLK, TFT_RST);

(中略)

void setup(void) {
Serial.begin(9600);
Serial.print("Hello! ST7735 TFT Test");
// SPI.setClockDivider(SPI_CLOCK_DIV128);

// Use this initializer if you're using a 1.8" TFT
tft.initR(INITR_BLUETAB); // initialize a ST7735S chip, black tab


動作の様子です。
クロックがArduino Pro Mini(3.3v)の10倍ありますので、描画が比べ物にならないほど高速です。



posted by boochow at 18:01| Comment(0) | ESP8266 | このブログの読者になる | 更新情報をチェックする
人気記事